defmodule BerrypodWeb.Shop.Pages.Contact do
  @moduledoc """
  Contact page handler for the unified Shop.Page LiveView.
  """

  import Phoenix.Component, only: [assign: 3]
  import Phoenix.LiveView, only: [push_navigate: 2, put_flash: 3]

  alias Berrypod.{ContactNotifier, Orders}
  alias BerrypodWeb.R
  alias Berrypod.Orders.OrderNotifier
  alias Berrypod.Pages
  alias BerrypodWeb.OrderLookupController

  def init(socket, _params, _uri) do
    page = Pages.get_page("contact")

    socket =
      socket
      |> assign(:page_title, "Contact")
      |> assign(
        :page_description,
        "Get in touch with us for any questions or help with your order."
      )
      |> assign(:og_url, R.url(R.contact()))
      |> assign(:tracking_state, :idle)
      |> assign(:page, page)

    {:noreply, socket}
  end

  def handle_params(_params, _uri, socket) do
    {:noreply, socket}
  end

  def handle_event("lookup_orders", %{"email" => email}, socket) do
    orders = Orders.list_orders_by_email(email)

    state =
      if orders == [] do
        :not_found
      else
        token = OrderLookupController.generate_token(email)
        link = BerrypodWeb.Endpoint.url() <> "/orders/verify/#{token}"
        OrderNotifier.deliver_order_lookup(email, link)
        :sent
      end

    {:noreply, assign(socket, :tracking_state, state)}
  end

  def handle_event("send_contact", params, socket) do
    case ContactNotifier.deliver_contact_message(params) do
      {:ok, _} ->
        {:noreply,
         socket
         |> put_flash(:info, "Message sent! We'll get back to you soon.")
         |> push_navigate(to: R.contact())}

      {:error, :invalid_params} ->
        {:noreply, put_flash(socket, :error, "Please fill in all required fields.")}

      {:error, _} ->
        {:noreply, put_flash(socket, :error, "Sorry, something went wrong. Please try again.")}
    end
  end

  def handle_event("reset_tracking", _params, socket) do
    {:noreply, assign(socket, :tracking_state, :idle)}
  end

  def handle_event(_event, _params, _socket), do: :cont
end
